gerrikoio
Published © MIT

BLE GP-O Controller | MIT App Inv + Feather M0 Bluefruit LE

A smartphone App that uses new MIT App Inventor BLE extension to connect with a Feather M0 Bluefruit LE and control up to 6 GP-Os

IntermediateProtip4 hours1,495
BLE GP-O Controller | MIT App Inv + Feather M0 Bluefruit LE

Things used in this project

Hardware components

Adafruit Feather M0 Bluefruit LE
×1
LED (generic)
LED (generic)
For Green LED's use this link: https://www.sparkfun.com/products/9592
×5
Resistor 100 ohm
Resistor 100 ohm
×5

Software apps and online services

MIT App Inventor
MIT App Inventor
Arduino IDE
Arduino IDE

Story

Read more

Schematics

ble_gpiocontroller_demo_HmWMsUnoNG.fzz

Code

MIT App Inventor aia file

AsciiDoc
No preview (download only).

Adafruit_bleuartGPIOcontrol_APPinventor.ino

Arduino
/*********************************************************************
 This is an example for our nRF51822 based Bluefruit LE modules

 Pick one up today in the adafruit shop!

 Adafruit invests time and resources providing this open source code,
 please support Adafruit and open-source hardware by purchasing
 products from Adafruit!

 MIT license, check LICENSE for more information
 All text above, and the splash screen below must be included in
 any redistribution
*********************************************************************/
/*********************************************************************
* This is modified program is linked to an MIT App Inventor App to control
* up to 6 GP-O's. This program only accepts data from teh App. It
* does not reply to the app in any way.
* 
* App developed by Gerrikoio, using an example provided with the nRF51822
* library from Adafruit.
* 
* MIT license applies.
* 
*********************************************************************/

#include <Arduino.h>
#include <SPI.h>
#if not defined (_VARIANT_ARDUINO_DUE_X_) && not defined (_VARIANT_ARDUINO_ZERO_)
  #include <SoftwareSerial.h>
#endif

#include "Adafruit_BLE.h"
#include "Adafruit_BluefruitLE_SPI.h"
#include "Adafruit_BluefruitLE_UART.h"

#include "BluefruitConfig.h"

/*=========================================================================
    APPLICATION SETTINGS

  FACTORYRESET_ENABLE     Perform a factory reset when running this sketch
 
                            Enabling this will put your Bluefruit LE module
                              in a 'known good' state and clear any config
                              data set in previous sketches or projects, so
                            running this at least once is a good idea.
 
                            When deploying your project, however, you will
                              want to disable factory reset by setting this
                              value to 0. If you are making changes to your
                            Bluefruit LE device via AT commands, and those
                              changes aren't persisting across resets, this
                              is the reason why. Factory reset will erase
                              the non-volatile memory where config data is
                              stored, setting it back to factory default
                              values.
   
                            Some sketches that require you to bond to a
                              central device (HID mouse, keyboard, etc.)
                              won't work at all with this feature enabled
                              since the factory reset will clear all of the
                              bonding data stored on the chip, meaning the
                              central device won't be able to reconnect.
    MINIMUM_FIRMWARE_VERSION  Minimum firmware version to have some new features
    MODE_LED_BEHAVIOUR        LED activity, valid options are
                              "DISABLE" or "MODE" or "BLEUART" or
                              "HWUART"  or "SPI"  or "MANUAL"
    -----------------------------------------------------------------------*/
    #define FACTORYRESET_ENABLE         1
    #define MINIMUM_FIRMWARE_VERSION    "0.6.6"
    #define MODE_LED_BEHAVIOUR          "MODE"
/*=========================================================================*/

// Create the bluefruit object, either software serial...uncomment these lines
/*
SoftwareSerial bluefruitSS = SoftwareSerial(BLUEFRUIT_SWUART_TXD_PIN, BLUEFRUIT_SWUART_RXD_PIN);

Adafruit_BluefruitLE_UART ble(bluefruitSS, BLUEFRUIT_UART_MODE_PIN,
                      BLUEFRUIT_UART_CTS_PIN, BLUEFRUIT_UART_RTS_PIN);
*/

/* ...or hardware serial, which does not need the RTS/CTS pins. Uncomment this line */
// Adafruit_BluefruitLE_UART ble(BLUEFRUIT_HWSERIAL_NAME, BLUEFRUIT_UART_MODE_PIN);

/* ...hardware SPI, using SCK/MOSI/MISO hardware SPI pins and then user selected CS/IRQ/RST */
Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_CS, BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);

/* ...software SPI, using SCK/MOSI/MISO user-defined SPI pins and then user selected CS/IRQ/RST */
//Adafruit_BluefruitLE_SPI ble(BLUEFRUIT_SPI_SCK, BLUEFRUIT_SPI_MISO,
//                             BLUEFRUIT_SPI_MOSI, BLUEFRUIT_SPI_CS,
//                             BLUEFRUIT_SPI_IRQ, BLUEFRUIT_SPI_RST);



// -------------- DEMO APP GP-O PIN REFERENCE --------------------------------------------------
// These are the pin reference values (if you do not want a pin set then enter a 0 in the array) 
// MIT App button "Pin1" is 1st item in the array (refers to Feather MO pin-5), button "Pin2" is the 2nd (refers to Feather MO pin-6) etc. 
// ---------------------------------------------------------------------------------------------
const byte pinRef[6] = {5, 6, 9, 10, 11, 13};

bool cmdStr = false;        // A flag to inform which GPIO pin selected

byte pinNo = 0;



// A small helper
void error(const __FlashStringHelper*err) {
  Serial.println(err);
  while (1);
}

/**************************************************************************/
/*!
    @brief  Sets up the HW an the BLE module (this function is called
            automatically on startup)
*/
/**************************************************************************/
void setup(void)
{
  delay(500);

  // Configure the pin modes
  for (byte i = 0; i < 6; i++) {
    pinMode(pinRef[i], OUTPUT);
    digitalWrite(pinRef[i], HIGH);
  }

  Serial.begin(115200);
  Serial.println(F("MIT App Inventor GPIO Control Example"));
  Serial.println(F("------------------------------------------------"));

  if ( !ble.begin(VERBOSE_MODE) )
  {
    error(F("Couldn't find Bluefruit, make sure it's in CoMmanD mode & check wiring?"));
  }

  if ( FACTORYRESET_ENABLE )
  {
    /* Perform a factory reset to make sure everything is in a known state */
    Serial.println(F("Performing a factory reset: "));
    if ( ! ble.factoryReset() ){
      error(F("Couldn't factory reset"));
    }
  }

  /* Disable command echo from Bluefruit */
  ble.echo(false);

  /* Print Bluefruit information */
  ble.info();

  ble.verbose(false);  // debug info is a little annoying after this point!

  Serial.println(F("Waiting for connection"));
  delay(500);
  for (byte i = 0; i < 6; i++) {
    digitalWrite(pinRef[i], LOW);
    delay(500);
  }


  /* Wait for connection */
  while (! ble.isConnected()) {
      delay(500);
  }

  Serial.println(F("******************************"));

  // LED Activity command is only supported from 0.6.6
  if ( ble.isVersionAtLeast(MINIMUM_FIRMWARE_VERSION) )
  {
    ble.sendCommandCheckOK("AT+HWModeLED=" MODE_LED_BEHAVIOUR);
  }

  // Set module to DATA mode
  Serial.println( F("Connected. Switching to Data mode!") );
  ble.setMode(BLUEFRUIT_MODE_DATA);
  Serial.println(F("******************************"));
}

/**************************************************************************/
/*!
    @brief  Constantly poll for new command or response data
*/
/**************************************************************************/
void loop(void)
{
  if (ble.available()) {
    byte c = ble.read();
    if (!cmdStr) {
      if (isAlpha((char)c)) {
        switch ((char)c) {
          case 'A':         // pin 1
            if (pinRef[0] != 0) {
              pinNo = pinRef[0];
              cmdStr = true;
            }
            break;
          case 'B':         // pin 2
            if (pinRef[1] != 0) {
              pinNo = pinRef[1];
              cmdStr = true;
            }
            break;
          case 'C':         // pin 3
            if (pinRef[2] != 0) {
              pinNo = pinRef[2];
              cmdStr = true;
            }
            break;
          case 'D':         // pin 4
            if (pinRef[3] != 0) {
              pinNo = pinRef[3];
              cmdStr = true;
            }
            break;
          case 'E':         // pin 5
            if (pinRef[4] != 0) {
              pinNo = pinRef[4];
              cmdStr = true;
            }
            break;
          case 'F':         // pin 6
            if (pinRef[5] != 0) {
              pinNo = pinRef[5];
              cmdStr = true;
            }
            break;
          default:
            Serial.print((char)c);
            Serial.println(F( " is not a valid GPIO pin reference"));
        }
      }
    }
    else {
      if (isDigit((char)c)) {
        if ((char)c == '0') {
          if (pinNo) digitalWrite(pinNo, LOW);
        }
        else if ((char)c == '1') {
          if (pinNo) digitalWrite(pinNo, HIGH);
        }
        else {
          Serial.print((char)c);
          Serial.print(F( " is not valid for GPIO pin: "));
          Serial.println(pinNo);
        }
      }
      cmdStr = false;
    }
  }
}

BluefruitConfig.h

C/C++
// COMMON SETTINGS
// ----------------------------------------------------------------------------------------------
// These settings are used in both SW UART, HW UART and SPI mode
// ----------------------------------------------------------------------------------------------
#define BUFSIZE                        128   // Size of the read buffer for incoming data
#define VERBOSE_MODE                   true  // If set to 'true' enables debug output


// SOFTWARE UART SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the pins that will be used for 'SW' serial.
// You should use this option if you are connecting the UART Friend to an UNO
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_SWUART_RXD_PIN       9    // Required for software serial!
#define BLUEFRUIT_SWUART_TXD_PIN       10   // Required for software serial!
#define BLUEFRUIT_UART_CTS_PIN         11   // Required for software serial!
#define BLUEFRUIT_UART_RTS_PIN         -1   // Optional, set to -1 if unused


// HARDWARE UART SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the HW serial port you are using. Uncomment
// this line if you are connecting the BLE to Leonardo/Micro or Flora
// ----------------------------------------------------------------------------------------------
#ifdef Serial1    // this makes it not complain on compilation if there's no Serial1
  #define BLUEFRUIT_HWSERIAL_NAME      Serial1
#endif


// SHARED UART SETTINGS
// ----------------------------------------------------------------------------------------------
// The following sets the optional Mode pin, its recommended but not required
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_UART_MODE_PIN        12    // Set to -1 if unused


// SHARED SPI SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the pins to use for HW and SW SPI communication.
// SCK, MISO and MOSI should be connected to the HW SPI pins on the Uno when
// using HW SPI.  This should be used with nRF51822 based Bluefruit LE modules
// that use SPI (Bluefruit LE SPI Friend).
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_SPI_CS               8
#define BLUEFRUIT_SPI_IRQ              7
#define BLUEFRUIT_SPI_RST              4    // Optional but recommended, set to -1 if unused

// SOFTWARE SPI SETTINGS
// ----------------------------------------------------------------------------------------------
// The following macros declare the pins to use for SW SPI communication.
// This should be used with nRF51822 based Bluefruit LE modules that use SPI
// (Bluefruit LE SPI Friend).
// ----------------------------------------------------------------------------------------------
#define BLUEFRUIT_SPI_SCK              13
#define BLUEFRUIT_SPI_MISO             12
#define BLUEFRUIT_SPI_MOSI             11

Credits

gerrikoio

gerrikoio

1 project • 5 followers
Dedicated IoT and M2M solution developer, unlocking value by connecting and protecting things.

Comments